Added .gitignore
[camargo/neiasound.git] / neiasound.pro
1 #
2 # neiasound Main Project File
3 #
4 # Copyright (c) 2015, Lucas Pires Camargo
5 # All rights reserved.
6 #
7 # Redistribution and use in source and binary forms, with or without modification,
8 # are permitted provided that the following conditions are met:
9 #
10 # 1. Redistributions of source code must retain the above copyright notice, this
11 # list of conditions and the following disclaimer.
12 #
13 # 2. Redistributions in binary form must reproduce the above copyright notice,
14 # this list of conditions and the following disclaimer in the documentation and/or
15 # other materials provided with the distribution.
16 #
17 # THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
18 # ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
19 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
20 # DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR
21 # ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
22 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
23 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON
24 # ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
25 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
26 # SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
27
28
29 QT += gui
30
31 TARGET = neiasound
32 TEMPLATE = lib
33 VERSION = 0.1
34
35 DEFINES += NEIASOUND_LIBRARY
36 CONFIG += NEIASOUND_USE_STB_VORBIS NEIASOUND_USE_WAVE_STREAM NEIASOUND_USE_SNDFILE
37
38 SOURCES += \
39     src/nsoundbag.cpp \
40     src/nsoundbuffer.cpp \
41     src/nsoundeffectparameters.cpp \
42     src/nsoundlistener.cpp \
43     src/nsoundsource.cpp \
44     src/nsoundstream.cpp \
45     src/nsoundstreamer.cpp \
46     src/nsoundstreamerplaylist.cpp \
47     src/nsoundsystem.cpp \
48     src/util/nefxhelper.cpp \
49     src/nsoundfilter.cpp
50
51 HEADERS += \
52     src/neiasound_global.h \
53     src/nsoundbag.h \
54     src/nsoundbuffer.h \
55     src/nsoundeffectparameters.h \
56     src/nsoundformat.h \
57     src/nsoundlistener.h \
58     src/nsoundsource.h \
59     src/nsoundsourcerole.h \
60     src/nsoundstream.h \
61     src/nsoundstreamer.h \
62     src/nsoundstreamerplaylist.h \
63     src/nsoundsystem.h \
64     src/util/efx-util.h \
65     src/nsoundfilter.h \
66     src/neiasound_al.h \
67     src/nsoundenums.h
68     #src/util/nefxHelper.h \
69
70 unix: CONFIG += link_pkgconfig
71
72 CONFIG(NEIASOUND_USE_STB_VORBIS) {
73     SOURCES += src/stb_vorbis/nvorbisstream.cpp
74     HEADERS += src/stb_vorbis/nvorbisstream.h
75 }
76
77 CONFIG(NEIASOUND_USE_WAVE_STREAM) {
78     SOURCES += src/wav/nwavestream.cpp
79     HEADERS += src/wav/nwavestream.h
80 }
81
82 CONFIG(NEIASOUND_USE_SNDFILE) {
83     SOURCES += src/sndfile/nsndfilestream.cpp
84     HEADERS += src/sndfile/nsndfilestream.h
85
86     unix: PKGCONFIG += sndfile
87     !unix {
88         INCLUDEPATH += $$LIBSNDFILE_INCLUDEPATH
89         LIBS += -L$$LIBSDFILE_LIBPATH -l$$LIBSNDFILE_LIB
90     }
91 }
92
93
94 unix {
95     target.path = /usr/lib
96     INSTALLS += target
97
98     INSTALL_PREFIX = /usr/include/neiasound
99     INSTALL_HEADERS = $$HEADERS
100     include(headerinstall.pri)
101
102     CONFIG += create_pc create_prl no_install_prl
103
104     QMAKE_PKGCONFIG_NAME = neiasound
105     QMAKE_PKGCONFIG_DESCRIPTION = Qt-like wrapper and utilities for OpenAL
106     QMAKE_PKGCONFIG_PREFIX = $$INSTALLBASE
107     QMAKE_PKGCONFIG_LIBDIR = $$target.path
108     QMAKE_PKGCONFIG_INCDIR = $$INSTALL_PREFIX
109     QMAKE_PKGCONFIG_VERSION = $$VERSION
110 }